Csound también puede direccionar el audio directamente a un archivo de sonido en su disco duro en lugar de como audio en vivo enviado al hardware de audio. Esto le da la posibilidad de escuchar los resultados de procesos muy complejos que su computadora puede no llegar a producir en tiempo real. O si quisiera hacer algo en Csound para luego importarlo en un editor de audio, o tal vez como el resultado final de una "pieza para cinta".1
Csound puede guardar su salida a archivos con formatos tales como wav, aiff o ogg (y otros menos populares), pero no mp3 debido a los problemas de patente y licencia de este último.
Guarde el código siguiente bajo el nombre Render.csd:
EXAMPLE 02E01_Render.csd
<CsoundSynthesizer>
<CsOptions>
-o Render.wav
</CsOptions>
<CsInstruments>
;Example by Alex Hofmann
instr 1
aSin poscil 0dbfs/4, 440
out aSin
endin
</CsInstruments>
<CsScore>
i 1 0 1
</CsScore>
</CsoundSynthesizer>
Abra una Te / Símbolo de Sistema / Consola y tipee:
csound /ruta/completa/Render.csd
Ahora bien, debido al cambio del argumento pasado a -o en las <CsOptions> de "-o dac" a "-o nombre de archivo", la salida de audio ya no se escribirá en tiempo real en su dispositivo de audio, sino en un archivo en su disco duro. El archivo se renderizará al directorio predeterminado (normalmente el directorio del Usuario) y este archivo se puede abrir y reproducir en cualquier reproductor o editor de audio, como por ejemplo Audacity.
La opción -o también se puede utilizar para escribir al archivo de salida en un directorio directorio. Para Windows sería algo así...
<CsOptions> -o c:/music/samples/Render.wav </CsOptions>
... y para Linux o Mac OSX:
<CsOptions> -o /Users/JSB/organ/tatata.wav </CsOptions>
La representación interna de los datos de audio en Csound se realiza usando números de coma flotante de 64 bits. Dependiendo de sus necesidades, debe decidir la precisión de su archivo de salida renderizado:
Para asegurarse de que el encabezado de su archivo de sonido se escribirá correctamente, debe utilizar la opción -W para un archivo WAV o -A para un archivo AIFF. Por ejemplo las siguientes opciones generarán el archivo "Wow.wav" utilizando el formato WAV con una precisión de 24 bits:
<CsOptions> -o Wow.wav -W -3 </CsOptions>
A veces es posible que desee tener simultáneamente salida en tiempo real y a un archivo en el disco, como cuando desee grabar una interpretación en vivo. Esto se puede lograr usando el opcode fout. Sólo tiene que especificar un nombre para el archivo de salida. El tipo de archivo y el formato están dados por un número, por ejemplo 18 especifica "wav de 24 bits" (consulte la página de manual para más información). El siguiente ejemplo genera una frecuencia y el movimiento de paneo de una onda senoidal, ambos aleatorios, y lo escribe en el archivo live_record.wav (en el mismo directorio en que se encuentra su archivo .csd):
EXAMPLE 02E02_RecordRT.csd
<CsoundSynthesizer>
<CsOptions>
-odac
</CsOptions>
<CsInstruments>
;Example by Joachim Heintz
sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1
seed 0 ;each time different seed for random
instr 1
kFreq randomi 400, 800, 1 ;random sliding frequency
aSig poscil .2, kFreq ;sine with this frequency
kPan randomi 0, 1, 1 ;random panning
aL, aR pan2 aSig, kPan ;stereo output signal
outs aL, aR ;live output
fout "live_record.wav", 18, aL, aR ;write to soundfile
endin
</CsInstruments>
<CsScore>
i 1 0 10
</CsScore>
</CsoundSynthesizer>
There has been error in communication with Booktype server. Not sure right now where is the problem.
You should refresh this page.