Como mencionabamos en la sección anterior, la frecuencia se define como el número de ciclos o períodos por segundo y se mide en Hertz. Si un tono tiene una frecuencia de 440 Hz, esto significa que completa 440 ciclos por segundo. Dada la frecuencia de un tono, se puede calcular fácilmente el período de cualquier sonido. Matemáticamente, el período es el recíproco de la frecuencia y viceversa. En forma de ecuación, esto se expresa de la siguiente manera:
Frecuencia = 1/Período Período = 1/Frecuencia
Por lo tanto, la frecuencia es la inversa del periodo. Una onda de 100 Hz de frecuencia tiene un período de 1/100 o 0,01 segundos. Así mismo una frecuencia de 256Hz tiene un período de 1/256 o 0.004 segundos. Para calcular la longitud de onda de un sonido en cualquier medio dado podemos utilizar la siguiente ecuación:
λ = Velocidad/Frecuencia
Por ejemplo, una onda de 1000 Hz cuyo medio es el aire (velocidad de difusión cercana a los 340 m/s) tiene una longitud de aproximadamente 340/1000 m = 34 cm.
Se acepta generalmente que el oído humano puede oír sonidos en el rango de 20 Hz y 20.000 Hz (20 kHz). Este límite superior tiende a disminuir con la edad debido a una condición conocida como presbiacusia, también llamada pérdida de la audición relacionada con la edad. La mayoría de los adultos pueden escuchar hasta aproximadamente los 16 kHz, mientras que la mayoría de los niños pueden oír más allá de esta frecuencia. En el extremo inferior del espectro, el oído humano no responde a frecuencias por debajo de los 20 Hz, siendo 40 o 50 Hz lo que la mayoría de las personas puede percibir.
Dicho esto, en el ejemplo siguiente se encontrará con que probablemente no percibirá el primer tono (10 Hz) nitampoco el último (20 kHz), pero debería oir los tonos restantes (100 Hz, 1000 Hz, 10000 Hz):
EXAMPLE 01B01_LimitsOfHearing.csd
<CsoundSynthesizer>
<CsOptions>
-odac -m0
</CsOptions>
<CsInstruments>
;ejemplo por joachim heintz
sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1
instr 1
prints "Reproduciendo %d Hertz!\n", p4
asig oscils .2, p4, 0
outs asig, asig
endin
</CsInstruments>
<CsScore>
i 1 0 2 10
i . + . 100
i . + . 1000
i . + . 10000
i . + . 20000
</CsScore>
</CsoundSynthesizer>
Una gran porción de la matemática básica tiene como objetivo la simplificación de ecuaciones complejas. Los atajos se toman todo el tiempo para hacer las cosas más fáciles de leer y equiparar. La multiplicación puede ser vista como una abreviatura de adiciones repetidas, por ejemplo, 5x10 = 5+5+5+5+5+5+5+5+5+5. De igual modo los exponentes son una forma abreviada de escribir multiplicaciones que se repiten, 3⁵ = 3x3x3x3x3. A su vez los logaritmos son la abreviatura de los exponentes y se utilizan en muchas áreas de la ciencia y la ingeniería en las que las cantidades varían en un rango amplio. Ejemplos de escalas logarítmicas incluyen la escala de decibelios, la escala de Richter para medir la magnitud de los terremotos y la escala astronómica de magnitud aparente. Las frecuencias musicales también trabajan sobre una escala logarítmica; más adelante diremos más sobre esto.
Los intervalos de la música describen la distancia entre dos notas. Cuando se trata de notación musical estándar, es fácil determinar un intervalo entre dos notas adyacentes. Por ejemplo, una quinta perfecta siempre se compone de 7 semitonos. Cuando se trata de valores expresados en Hz las cosas son diferentes. Una diferencia de, por ejemplo 100 Hz, no siempre equivale a un mismo intervalo musical. Esto se debe a que los intervalos musicales tal como los oímos equivalen en Hz a relaciones de frecuencia y no a cantidades absolutas. Una octava por ejemplo es siempre una relación de 2 a 1. Es decir, cada vez que duplicamos un valor en Hz obtendremos el intervalo musical de una octava.
Consideremos lo siguiente. Una flauta puede tocar la nota La a 440Hz. Si el intreprete toca otro La una octava por encima de la primera, es decir a 880 Hz, la diferencia será de 440 Hz. Pero consideremos ahora el flautín, el instrumento de mayor registro de la orquesta. El piccolo puede producir un sonido de 2000 Hz, pero también puede sonar una octava por encima de esta nota a 4000 Hz (2 x 2000 Hz). Mientras que la diferencia en Hertz entre las primeras dos notas de la flauta es sólo de 440 Hz, la diferencia entre las dos notas del piccolo es de 1000 Hz. Sin embargo, en ambos casos percibimos un intervalo de octava.
Lo que todo esto demuestra es que cuanto mayores sean las alturas, mayor deberá ser la diferencia en Hertz para que reconozcamos el mismo intervalo musical. Podemos utilizar relaciones simples para representar un número de intervalos conocidos; por ejemplo, el unísono (1:1), la octava (2:1), la quinta justa (3:2), la cuarta justa (4:3), la tercera mayor (5:4) y la tercera menor (6:5); pero debe tenerse en cuenta que la mayoría de estos intervalos están representados con absoluta precisión solamente cuando se utiliza el temperamente justo. En el temperamento igual, el método más utilizado para la afinación de muchos de nuestros instrumentos en Occidente, solamente el unísono y la octava se representan con estas proporciones precisas.
El siguiente ejemplo muestra la diferencia entre la adición de una cierta frecuencia y la aplicación de una relación. En primer lugar, las frecuencias de 100, 400 y 800 Hz obtienen una adición de 100 Hz. Esto suena muy diferente en cada caso, aunque la cantidad de frecuencia añadida sea la misma. En segundo lugar, la relación de 3/2 (quinta justa) se aplica a las frecuencias antes mencionadas. En consecuencia, aunque el desplazamiento de frecuencia sea diferente en cada caso, el intervalo percibido será el mismo.
EXAMPLE 01B02_Adding_vs_ratio.csd
<CsoundSynthesizer>
<CsOptions>
-odac -m0
</CsOptions>
<CsInstruments>
;ejemplo por joachim heintz
sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1
instr 1
prints "Reproduciendo %d Hertz!\n", p4
asig oscils .2, p4, 0
outs asig, asig
endin
instr 2
prints "Sumando %d Hertz a %d Hertz!\n", p5, p4
asig oscils .2, p4+p5, 0
outs asig, asig
endin
instr 3
prints "Aplicando la relacion %f (sumando %d Hertz)
a %d Hertz!\n", p5, p4*p5, p4
asig oscils .2, p4*p5, 0
outs asig, asig
endin
</CsInstruments>
<CsScore>
;sumando una frecuencia determinada (instr 2)
i 1 0 1 100
i 2 1 1 100 100
i 1 3 1 400
i 2 4 1 400 100
i 1 6 1 800
i 2 7 1 800 100
;aplicando una relación (instr 3)
i 1 10 1 100
i 3 11 1 100 [3/2]
i 1 13 1 400
i 3 14 1 400 [3/2]
i 1 16 1 800
i 3 17 1 800 [3/2]
</CsScore>
</CsoundSynthesizer>
Entonces, ¿qué hay de las operaciones matemáticas mencionadas al principio de esta sección? Como algunos lectores sabrán, el método preferido en la actualidad para afinar los instrumentos en Occidente se basa en el temperamento igual. Básicamente, esto significa que todas las octavas se dividen en 12 intervalos iguales. Por lo tanto un semitono tiene una relación de 2(1/12), que equivale aproximadamente a 1,059463.
¿Qué hay de los logaritmos? Como se dijo anteriormente, los logaritmos son una forma abreviada de escribir exponentes. 2(1/12) = 1.059463 también puede escribirse como log2 (1,059463) = 1/12. Por lo tanto las frecuencias usadas en la música se basan en una escala logarítmica.
Csound puede lidiar fácilmente con las notas MIDI y posee incorporadas funciones para convertir las notas MIDI a los valores en Hertz correspondientes y viceversa. En el protocolo MIDI un La440 es igual a La4 y corresponde a la nota MIDI 69. Se puede pensar en La4 como el cuarto La partiendo del La más bajo que podemos oír; bueno, que casi podemos oír.
Precaución: al igual que sucede con muchos de los 'estándares', a veces existe un desacuerdo respecto a la correlación entre frecuencia y número de octava. En algunos lugares se utiliza la denominación La3 para referirse al La440.
There has been error in communication with Booktype server. Not sure right now where is the problem.
You should refresh this page.